C语言、汇编混合编程示例

mp4

整理了一下以前学习汇编时写的代码，发上来看看是否对各位有所帮助。

c调用asm写的函数，适用于32位机
main.c

1. 
   
2. #include <stdio.h>
   
3. 
   
4. int printf_minus(int num1, int num2);
   
5. 
   
6. int main()
   
7. {
   
8.         int n1,n2;
   
9. 
   
10.         n1=23;
    
11.         n2=12;
    
12. 
    
13.         printf("c:\n");
    
14.         printf("%d - %d = %d\n", n1, n2, n1-n2);
    
15. 
    
16.         printf("asm:\n");
    
17.         printf_minus(n1,n2);
    
18.         return 0;
    
19. }
    

复制代码

function.asm

1. 
   
2. extern printf
   
3. global printf_minus
   
4. 
   
5. [section .text]
   
6. printf_minus:
   
7. mov eax, [esp+4]        ; num1
   
8. sub eax, [esp+8]        ; num2
   
9. push eax                     ; num1-num2
   
10. push dword [esp+12]
    
11. push dword [esp+12]
    
12. push dword fmt
    
13. call printf                   ; printf(fmt, num1, num2, num1-num2);
    
14. add esp, 16
    
15. ret
    
16. 
    
17. fmt:
    
18. db "%d - %d = %d",0ah,0
    

复制代码

编译：
nasm -f elf function.asm
gcc -c main.c
gcc -o test main.o function.o

运行：
./test
c:
23 - 12 = 11
asm:
23 - 12 = 11

mp4

再发一个：用汇编获取CPU ID，这回用asm编写库，c调用库

cpuid.asm

1. 
   
2. extern _GLOBAL_OFFSET_TABLE_
   
3. 
   
4. global get_cpuid:function
   
5. 
   
6. %macro get_GOT 0
   
7. call %%getgot
   
8. %%getgot:
   
9. pop ebx
   
10. add ebx,_GLOBAL_OFFSET_TABLE_+$$-%%getgot wrt ..gotpc
    
11. %endmacro
    
12. 
    
13. [section .data]
    
14. ver db "CPUID library version 0.0.1",0xa,0
    
15. len equ $-ver
    
16. 
    
17. [section .text]
    
18. _start:
    
19. get_GOT
    
20. mov edx,len
    
21. lea ecx,[ebx+ver wrt ..gotoff]
    
22. mov ebx,1
    
23. mov eax,4
    
24. int 0x80
    
25. mov ebx,0
    
26. mov eax,1
    
27. int 0x80
    
28. 
    
29. get_cpuid:
    
30. push edi
    
31. mov edi,[esp+8]
    
32. push ebx
    
33. push ecx
    
34. push edx
    
35. xor eax,eax
    
36. cpuid
    
37. mov [edi],ebx
    
38. mov [edi+4],edx
    
39. mov [edi+8],ecx
    
40. mov [edi+12],byte 0
    
41. pop edx
    
42. pop ecx
    
43. pop ebx
    
44. pop edi
    
45. ret
    

复制代码

cpuid.h

1. 
   
2. #ifndef _CPUID_H
   
3. #define _CPUID_H        1
   
4. 
   
5. void get_cpuid(char *buf);
   
6. 
   
7. #endif
   

复制代码

1. 
   
2. #include <stdio.h>
   
3. #include <stdlib.h>
   
4. #include "cpuid.h"
   
5. 
   
6. int main(int argc, char *argv[])
   
7. {
   
8.         char buf[16];
   
9. 
   
10.         get_cpuid(buf);
    
11.         printf("The processor vender is "%s"\n", buf);
    
12.         exit(EXIT_SUCCESS);
    
13. }
    

复制代码

编译：
nasm -f elf cpuid.asm
ld -shared -o libcpuid.so cpuid.o
gcc -o demo demo.o -L. -lcpuid

运行：
./libcpuid.so
CPUID library version 0.0.1

env LD_LIBRARY_PATH=. ./demo
The processor vender is "GenuineIntel"


静态库：
nasm -f elf cpuid.asm
ar cr libcpuid.a cpuid.o
gcc -o demo demo.o libcpuid.a

./demo
The processor vender is "GenuineIntel"

fly0365

very good!

wugaohu

Post by fly0365;1775537
very good!

能不能总结一下？

huyongzs

第一个就是一个参数传递的问题
有个小难点就是
push dword [esp+12]
push dword [esp+12]
其实没什么，就是堆栈在不断的增长
第二个程序，我曾经做过一个dos版本的。其主要技术就是使用了一个cpuid指令
那些宏着实的很迷惑人。

huyongzs

为什么会有这一段？请高手指教~！看样子像是系统功能的调用.但是具体是干什么的为什么要有，不晓得的
_start:
get_GOT
mov edx,len
lea ecx,[ebx+ver wrt ..gotoff]
mov ebx,1
mov eax,4
int 0x80
mov ebx,0
mov eax,1
int 0x80

huyongzs

上边的问题经过查找发现是
　　.long SYMBOL_NAME(sys_exit)/*1*/
　　.long SYMBOL_NAME(sys_fork)
　　.long SYMBOL_NAME(sys_read)
　　.long SYMBOL_NAME(sys_write)/*4*/
看来那两个系统调用是用来显示什么的。第一个很可能就是显示lea ecx,[ebx+ver wrt ..gotoff]的字符串。第二个结束程序.